

**2021-2022 Spring CS315 Programing Languages Project I**

Group 14

Dominica Language

Members

Ferhat Korkmaz 21901940 Section 1

Melih Fazıl Keskin 21901831 Section 1

Kylian Djermoune 22103997 Section 1

**Name of the language:** Dominica

**BNF Description of Dominica Language**

**1) Types and Constants**

<set\_indicator> ::= “\_”

<LB> ::= “{“

<RB> ::= “}”

<LP> ::= “(“

<RP> ::= “)”

<return> ::= “return”

<end\_of\_stmt> ::= “;”

<line\_comment\_start> ::= “#”

<new\_line> ::= “\n”

<letter\_char> ::= [a-zA-Z]

<ascii\_char>  ::= [ -!#-~]

<digit> ::= [0-9]

<quote> ::= “"”

<column> ::= “:”

<sign> ::= + | -

<exclamation\_mark> ::= “!”

<and\_op> ::= “&&”

<or\_op> ::= “||”

<equals\_op> ::= “==”

<func\_type> ::= “func\_”

<not\_equals\_op> ::= “!=”

<greater\_than\_op> ::= “>”

<greater\_equal\_op> ::= “>=”

<less\_than\_op> ::= “<”

<less\_equal\_op> ::= “<=”

<comma> ::= “,”

<mul\_div\_sign> ::= \* | /

<dot> ::= “.”

<empty\_grammar\_rule> ::= “”

<assignment\_op> ::= “=”

<type\_name> ::= “int” | “string” | “bool” | “double” | “elm”

<set\_type> ::= “set”

<set\_add\_op> ::= “++”

<set\_remove\_op> ::= “--”

<set\_union\_op> ::= “U”

<set\_intersection\_op> ::= “^"

<set\_difference\_op> ::= “\”

<set\_delete\_op> ::= “delete”

<set\_is\_subset> ::= “C”

<set\_is\_superset> ::= “@”

<set\_is\_an\_element\_of> ::= “E”

<set\_are\_disjoint> ::= “D”

<main> ::= “main()”

**2) Program**

<Dominica> ::= <main><LB><RB>

| <main><LB><stmt\_list><RB>

   | <main><LB><RB><function\_list>

   | <main><LB><stmt\_list><RB><function\_list>

<function\_list> ::= <function> | <function><function\_list>

<stmt\_list> ::= <stmt> | <stmt><stmt\_list>

**3) Identifiers and Variables**

**-Identifiers**

<function\_identifier> ::= <func\_type><identifier>

<identifier> ::= <letter\_char><letter\_char> | <letter\_char><digit> |<identifier><letter\_char>

| <identifier><digit>

<set\_identifier> ::= <set\_indicator><letter\_char> | <set\_indicator><digit>

| <set\_identifier><letter\_char>  | <set\_identifier><digit>

**-Variables**

<set> ::= <LB><RB> | <LB><set\_init\_list><RB>

<set\_init\_list> ::= <identifier>  | <type> | <identifier><comma><set\_init\_list>

| <type><comma><set\_init\_list>

<type> ::= <integer> | <string> | <double> | <bool>

<string> ::= <quote><quote> | <quote><string\_term><quote>

<string\_term> ::= <ascii\_char> | <string\_term><ascii\_char>

<integer> ::= <digit> | <sign><digit> | <digit><integer> | <sign><digit><integer>

<double> ::= [<sign>]{<digit>}[<dot>]{<digit>}

<bool> ::= true | false

**4) Statements**

<stmt> ::= <expression><end\_of\_stmt> | <conditional\_stmt><end\_of\_stmt>

| <loop\_stmt><end\_of\_stmt>   
 | <comment\_stmt><new\_line>

**5) Loops**

<loop\_stmt> ::= <for\_loop> | <while\_loop>

<for\_loop> ::= <reg\_for\_loop> | <set\_for\_loop>

<reg\_for\_loop>::= for<LP><variable\_declaration><end\_of\_stmt><logical\_expression><end\_of\_stmt><assignment\_expression><RP><LB><stmt\_list><RB>

<set\_for\_loop>::=  
for<LP><set\_identifier><column><set\_identifier><RP><LB><stmt\_list><RB> | for<LP><set\_identifier><column><integer><column><set\_identifier><RP><LB><stmt\_list><RP> | for<LP><set\_identifier><column><integer><column><identifier><RP><LB><stmt\_list><RP>

<while\_loop> ::= while<LP><logical\_expression><RP><LB><stmt\_list><RB>

**6) Conditionals**

<conditional\_stmt> ::= if<LP><logical\_expression><RP><LB><stmt\_list><RB> | if<LP><logical\_expression><RP><LB><stmt\_list><RB>else<LB><stmt\_list><RB> | if<LP><logical\_expression><RP><LB><stmt\_list><RB>else<conditional\_stmt>

**-Logical Expressions**

<logical\_expression> ::= <regular\_logic> | <set\_logic>  
 | <logical\_expresion><and\_op><regular\_logic>  
 | <logical\_expresion><or\_op><regular\_logic>

| <logical\_expresion><and\_op><set\_logic>  
 | <logical\_expresion><or\_op><set\_logic>

| <exclamation\_mark><LP><logical\_expression><RP>

<regular\_logic> ::= <regular\_logic\_types>

| <regular\_logic\_types><equals\_op><regular\_logic\_types>

| <arithmetic\_operation><equals\_op><arithmetic\_operation>

| <regular\_logic\_types><not\_equals\_op><regular\_logic\_types>

| <arithmetic\_operation><not\_equals\_op><arithmetic\_operation>

| <arithmetic\_operation><greater\_equal\_op><arithmetic\_operation>

| <arithmetic\_operation><less\_equal\_op><arithmetic\_operation>

| <arithmetic\_operation><greater\_than\_op><arithmetic\_operation>

| <arithmetic\_operation><less\_than\_op><arithmetic\_operation>

<regular\_logic\_types> ::= <bool> | <identifier>

<set\_logic> ::= <identifier><set\_is\_an\_element\_of><set>

| <type><set\_is\_an\_element\_of><set>

| <identifier><set\_is\_an\_element\_of><set\_identifier>

| <type><set\_is\_an\_element\_of><set\_identifier>

| <set\_operation><set\_is\_subset><set\_operation>

| <set\_operation><set\_is\_superset><set\_operation>

| <set\_operation><set\_are\_disjoint><set\_operation>

**7) Expressions**

<expression> ::= <variable\_declaration> | <assignment\_expression> | <function\_call> | <set\_expression> | <set\_declaration> | <set\_assignment>

<variable\_declaration>::= <type\_name><identifier><assignment\_op><type>

| <type\_name><identifier><assignment\_op><arithmetic\_operation>

     | <type\_name><identifier><assignment\_op><logical\_expression>

| <type\_name><identifier><assignment\_op><identifier>

| <type\_name><identifier><assignment\_op><function\_call>

<assignment\_expression> ::= <identifier><assignment\_op><type>  
 | <identifier><assignment\_op><arithmetic\_operation>

| <identifier><assignment\_op><logical\_expression>  
 | <identifier><assignment\_op><identifier>

| <identifier><assignment\_op><function\_call>

**8) Sets**

<set\_declaration> ::= <set\_type><set\_identifier><assignment\_op><set>

| <set\_type><set\_identifier><assignment\_op><set\_operation>

| <set\_type><set\_identifier><assignment\_op><function\_call>

<set\_assignment> ::= <set\_identifier><assignment\_op><set>  
 | <set\_identifier><assignment\_op><set\_operation>  
 | <set\_identifier><assignment\_op><function\_call>

<set\_expression> ::= <set\_identifier><set\_add\_op>< type >

| <set\_identifier><set\_remove\_op>< type >

| <set\_identifier><set\_add\_op><identifier>

| <set\_identifier><set\_remove\_op><identifier>

| <set\_delete\_op><set\_identifier>

<set\_operation> ::= <set\_term> | <set\_operation><set\_intersection\_op><set\_term>

| <set\_operation><set\_difference\_op><set\_term>

| <set\_operation><set\_union\_op><set\_term>

<set\_term> ::= <set\_identifier> | <set>  | <LP><set\_operation><RP>

**9) Arithmetic Operations**

<arithmetic\_operation> ::= <arithmetic\_term>

| <arithmetic\_operation><sign><arithmetic\_term>

<arithmetic\_term> ::= <arithmetic\_term><mul\_div\_sign><arithmetic\_factor>

| <arithmetic\_factor>

<arithmetic\_factor> ::= <LP><arithmetic\_operation><RP> | <identifier> | <integer>

| <double>

**10) Functions**

**-Function Definition**

<function> ::= <type\_name><function\_identifier><LP><RP><LB><stmt\_list><return><identifier><RB> | <type\_name><function\_identifier><LP><RP><LB><stmt\_list><return><set\_identifier><RB> |   
<type\_name><function\_identifier><LP><RP><LB><stmt\_list><return><type><RB> | <type\_name><function\_identifier><LP><RP><LB><stmt\_list><return><set><RB> | <type\_name><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><identifier><RB> |   
<type\_name><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><set\_identifier><RB> | <type\_name><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><type><RB> | <type\_name><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><set><RB> |<set\_type><function\_identifier><LP><RP><LB><stmt\_list><return><identifier><RB> | <set\_type><function\_identifier><LP><RP><LB><stmt\_list><return><set\_identifier><RB> |   
<set\_type><function\_identifier><LP><RP><LB><stmt\_list><return><type><RB> | <set\_type><function\_identifier><LP><RP><LB><stmt\_list><return><set><RB> | <set\_type><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><identifier><RB> |   
<set\_type><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><set\_identifier><RB> | <set\_type><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><type><RB> | <set\_type><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><set><RB>

**-Function Call**

<function\_call> ::= <function\_identifier><LP><RP>

|<function\_identifier><LP><arg\_list><RP>

| <primitive\_function\_call>

<primitive\_function\_call> ::= n<LP><set\_operation><RP> | pow<LP><set\_operation><RP>

| cartesian<LP><set\_operation><comma><set\_operation><RP>

| print<LP><set\_operation><RP>

| print<LP><string><RP>

| print<LP><identifier><RP>

         | scan<LP><identifier><RP>

| scan<LP><set\_identifier><RP>

| fread<LP><string><RP>

| fwrite<LP><string><comma><string><RP>

| fwrite<LP><set\_operation><comma><string><RP>

**-Lists**

<arg\_list> ::= <identifier> | <set\_identifier> | <identifier><comma><param\_list>

| <set\_identifier><comma><param\_list>

<param\_list> ::= <type\_name><identifier> | <set\_type><set\_identifier>

| <type\_name><identifier><comma><param\_list>

| <set\_type><set\_identifier><comma><param\_list>

**10) Comments**

<comment\_stmt> ::= <line\_comment\_start><string\_term>

**Explanation of Dominica Language Constructs**

**Constants & Symbols**

* <set\_indicator> ::= “\_”

This construct represents “\_” symbol and it can be used at the beginning of <set\_identifier> to make it distinct than <identifier>

* <LB> ::= “{“

This construct represents the left curly braces.

* <RB> ::= “}”

This construct represents the right curly braces.

* <LP> ::= “(“

This construct represents the left parenthesis.

* <RP> ::= “)”

This construct represents the right parenthesis.

* <return> ::= “return”

This construct is used to represent “return” for returning a variable or set in the functions.

* <end\_of\_stmt> ::= “;”

This construct represents semi column and it is used at the end of statements.

* <line\_comment\_start> ::= “#”

This construct represents ‘#’ and used at the beginning of line comments.

* <new\_line> ::= “\n”

This construct represents the new line character.

* <letter\_char> ::= [a-zA-Z]

This construct represents a single letter.

* <ascii\_char>  ::= [ -!#-~]

This construct represents all of the ASCII characters except quote. It is because of preventing the confusion with string indicator <quote>

* <digit> ::= [0-9]

This construct represents a single digit.

* <quote> ::= “"”

This construct represents quote sign and it is used for indicating strings.

* <column> ::= “:”

This construct represents column and it is used in set for loops.

* <sign> ::= + | -

This construct represents the minus and plus to indicate the sign of numbers.

* <exclamation\_mark> ::= “!”

This construct represents the exclamation mark and it is used for reversing the result of a logic operation.

* <and\_op>::= “&&”

This construct represents ‘&&’ symbol and it is used as AND operation in logic operations.

* <or\_op>::= “||”

This construct represents ‘||’ symbol and it is used as OR operation in logic operations.

* <equals\_op> ::= “==”

This construct represents ‘==’ symbol and it is used for checking equality in logical operations.

* <func\_type> ::= “func\_”

This construct represents the “func\_” word and it is used at the beginning of <function\_identifier> to make it distinct from <identifier>

* <not\_equals\_op> ::= “!=”

This construct represents ‘!=’ symbol and it is used for checking equality in logical operations.

* <greater\_than\_op> ::= “>”

This construct represents ‘>’ symbol and it is used for checking if the left-hand side greater than right-hand side in logical operations.

* <greater\_equal\_op> ::= “>=”

This construct represents ‘>=’ symbol and it is used for checking if the left-hand side greater than or equal to right-hand side in logical operations.

* <less\_than\_op> ::= “<”

This construct represents ‘<’ symbol and it is used for checking if the left-hand side less than right-hand side in logical operations.

* <less\_equal\_op> ::= “<=”

This construct represents ‘<=’ symbol and it is used for checking if the left-hand side less than or equal to right-hand side in logical operations

* <comma> ::= “,”

This construct represents the comma and it is used for separating identifiers or types in set declaration or <param\_list> or <arg\_list>.

* <mul\_div\_sign> ::= \* | /

This construct represents the symbols for multiplication and division.

* <dot> ::= “.”

This construct represents the dot which is used in the representation of doubles.

* <empty\_grammar\_rule> ::= “”

This construct represents nothing. It makes our grammar more readable when we have an empty rule.

* <assignment\_op> ::= “=”

This construct represents the ‘=’ symbol which is used for assigning values to identifiers.

* <type\_name> ::= “int” | “string” | “bool” | “double” | “elm”

This construct represents the reserved words for type names of variables.

* <set\_type> ::= “set”

This construct represents the reserved word for type name of set.

* <set\_add\_op> ::= “++”

This construct represents the symbol ‘++’, which is used for adding an element to a set.

* <set\_remove\_op> ::= “--”

This construct represents the symbol ‘--’, which is used for removing an element from a set.

* <set\_union\_op> ::= “U”

This construct represents the symbol ‘U’ which is used for creating union of two sets. We selected this symbol because it is similar to its mathematical notation.

* <set\_intersection\_op> ::= “^"

This construct represents the symbol ‘^’ which is used for taking the intersection of two sets. We selected this symbol because it is similar to its mathematical notation.

* <set\_difference\_op> ::= “\”

This construct represents the symbol ‘\’ which is used for finding the difference of two sets. We selected this symbol because it is similar to its mathematical notation.

* <set\_delete\_op> ::= “delete”

This construct represents the reserved word for the deletion of a set.

* <set\_is\_subset> ::= “C”

This construct represents ‘C’ symbol and it is used in logical set operations for determining if the left-hand side is a subset of the right-hand side. We selected this symbol because it is similar to its mathematical notation.

* <set\_is\_superset> ::= “@”

This construct represents ‘@’ symbol and it is used in logical set operations for determining if the left-hand side is the superset of the right-hand side. We selected this symbol because it is looks like there are two circles and one is inside another. It is similar to Venn Diagram.

* <set\_is\_an\_element\_of> ::= “E”

This construct represents ‘E’ symbol and it is used in logical set operations for determining if the left-hand side is an element of right-hand side. We selected this symbol because it is similar to its mathematical notation.

* <set\_are\_disjoint> ::= “D”

This construct represents ‘D’ symbol and it is used in logical set operations for determining if the two sets are disjoint. We selected this symbol because as the first letter for disjoint.

* <main> ::= “main()”

This construct represents the reserved word for the main call in the program.

**Program Structure**

* <Dominica> ::= <main><LB><RB>

| <main><LB><stmt\_list><RB>

| <main><LB><RB><function\_list>

| <main><LB><stmt\_list><RB><function\_list>

Dominica language has to be consisted of a <main> means main() and it has to be followed by <LB> and <RB>, which are curly braces.

* <stmt\_list> ::= <stmt> | <stmt><stmt\_list>

Inside the curly braces, there can be <stmt\_list>. It is consisted of multiple <stmt>, which are statements. These statements are the instructions which user wants to execute during worktime.

* <function\_list> ::= <function> | <function><function\_list>

Also, function definitions can be included in <function\_list>, at outside of the curly braces. It is consisted of multiple <function>, which are function definitions. Keeping function definitions at outside of the main program increases the writability.

**Variables**

We have set, integer, double, string, bool and elm as variables in our language.

* <set> ::= <LB><RB> | <LB><set\_init\_list><RB>

The variable type set it is indicated with left and right braces. The reason why we choose having braces to indicate sets is that it is similar to mathematical set notations. Also, it increases the readability and reliability. Inside these braces, it may have <set\_init\_list>. Otherwise, it is an empty set.

* <set\_init\_list> ::= <identifier>  | <type> | <identifier><comma><set\_init\_list>

| <type><comma><set\_init\_list>

<set\_init\_list> can be consist of all the other variable types or their identifiers other than sets. They are separated with comma to increase readability and reliability.

* <type> ::= <integer> | <string> | <double> | <bool>

<type> is one of the all the other variables in Dominica language. Also, it is equivalent to variable type elm, to which any type of variable other than set can be assigned.

* <string> ::= <quote><quote> | <quote><string\_term><quote>

String is a variable which is consists of combinations of ASCII characters(except quote). It is indicated with quotes. Inside the quotes, it can contain <string\_term>. Otherwise, it is an empty string.

* <string\_term> ::= <ascii\_char> | <string\_term><ascii\_char>

<string\_term> is the combination of ASCII characters(except quote). The reason why quote mark is not included is that it may cause a confusion with string indicator <quote>.

* <integer> ::= <digit> | <sign><digit> | <digit><integer> | <sign><digit><integer>

The representation of integer variables can be with sign or without a sign.

* <double> ::= [<sign>]{<digit>}[<dot>]{<digit>}

The representation of double variables can be with sign or without a sign. Also, it can be without any digit before or after the dot. Also, it can be without a dot just like an integer. These options increase the writability.

* <bool> ::= true | false

Bool variables can have two values. They are true or false.

**Identifiers**

* <function\_identifier> ::= <func\_type><identifier>

<function\_identifier> is used to identify functions. It has to start with “func\_” reserved word which makes the distinction between it and the <identifier>. This condition increases reliability and readability but there is a little decrease in writability.

* <identifier> ::= <letter\_char><letter\_char> | <letter\_char><digit>

| <identifier><letter\_char>  | <identifier><digit>

Identifier is used to identify <type> variables. It has to be consisted of minimum two characters and first one has to be <letter\_char>. It is for making the distinction between identifiers and operators we used like ‘C’ or ‘U’. This increase reliability but decrease writability.

* <set\_identifier> ::= <set\_indicator><letter\_char> | <set\_indicator><digit>

| <set\_identifier><letter\_char>  | <set\_identifier><digit>

<set\_identifier> has to start with an the ‘\_’ char which is the <set\_indicator>. In that way, the distinction between <set\_identifier> and <identifier> is made. It makes easy to do not include any set in a set. Therefore, the reliability increases.

**Statements**

* <stmt> ::= <expression><end\_of\_stmt> | <conditional\_stmt><end\_of\_stmt>

| <loop\_stmt><end\_of\_stmt> | <comment\_stmt><new\_line>

<stmt> holds for one instruction in the Dominica. Unless it is a <comment\_stmt>, it has to end with ‘;’ character, which is represented by <end\_of\_stmt>. It increases readability and reliability. If it is a <comment\_stmt>, it has to end with a new line character to indicate that comment has ended.

**Expressions**

* <expression> ::= <variable\_declaration> | <assignment\_expression> | <function\_call

| <set\_expression> | <set\_declaration> | <set\_assignment>

<expression> is the common instructions in a programming language which generally occupies only one line. It can be on of the constructs which are indicated in its BNF definition.

**Declarations**

* <variable\_declaration>::= <type\_name><identifier><assignment\_op><type>

| <type\_name><identifier><assignment\_op><arithmetic\_operation>

     | <type\_name><identifier><assignment\_op><logical\_expression>

| <type\_name><identifier><assignment\_op><identifier>

| <type\_name><identifier><assignment\_op><function\_call>

Variable declaration for the types has to be done by assigning a value. The reason behind this is increasing reliability. To be more precise:

~~int count;~~ #This is not correct

int count = 5 \* 4; #This is correct

Assignment operator is used in the declarations and left-hand side has to be <type\_name> followed by <identifier>. Right-hand side can be one of the constructs in the BNF definition. The right-hand side should match the variable type on the left-hand side unless the<type\_name> is “elm”. “elm” type can contain any of the type among integer, string, double or string.

* <set\_declaration> ::= <set\_type><set\_identifier><assignment\_op><set>

| <set\_type><set\_identifier><assignment\_op><set\_operation>

| <set\_type><set\_identifier><assignment\_op><function\_call>

Set declaration for the sets has to be done by assigning a set similar to variable declaration. The reason behind this is increasing reliability. To be more precise:

~~set \_mySet;~~ #This is not correct

set \_mySet = { count, true, 5, “Dominica” }; #This is correct

Assignment operator is used in the declaration of the set and left-hand side has to be <set\_type> reserved word followed by a <set\_identifier>. Right-hand side can be one of the constructs in the BNF definition.

**Assignments**

* <assignment\_expression> ::= <identifier><assignment\_op><type>  
   | <identifier><assignment\_op><arithmetic\_operation>

| <identifier><assignment\_op><logical\_expression>  
 | <identifier><assignment\_op><identifier>

| <identifier><assignment\_op><function\_call>

Left-hand side of the assignment expression has to be an identifier. Right-hand side can be one of the constructs in the BNF definition. The right-hand side should match the variable type on the left-hand side unless the identifier declared as “elm” type. “elm” type can contain any of the type among integer, string, double or string.

* <set\_assignment> ::= <set\_identifier><assignment\_op><set>  
   | <set\_identifier><assignment\_op><set\_operation>  
   | <set\_identifier><assignment\_op><function\_call>

Left-hand side of the assignment expression for the <set\_assignment> has to be a <set\_identifier>. Right-hand side can be one of the constructs in the BNF definition.

**Sets**

* <set\_expression> ::= <set\_identifier><set\_add\_op>< type >

| <set\_identifier><set\_remove\_op>< type >

| <set\_identifier><set\_add\_op><identifier>

| <set\_identifier><set\_remove\_op><identifier>

| <set\_delete\_op><set\_identifier>

<set\_expression> holds for the expressions which are related to sets and which can not be written in assignment or declaration expressions. It contains three operations. One of them is adding an item to the set. ‘++’ is used as <set\_add\_op> and left-hand side has to be a <set\_identifier>. Right hand-side can be a type or an identifier.

One of the others is deleting an item from the set. ‘--’ is used as <set\_remove\_op> and left-hand side has to be a set identifier. Right hand-side can be a type or an identifier.

The other is deleting a set. ‘delete’ reserved keyword is used as <set\_delete\_op> and the expression has to start with it. Then, it has to be followed by a set identifier.

* <set\_operation> ::= <set\_term> | <set\_operation><set\_intersection\_op><set\_term>

| <set\_operation><set\_difference\_op><set\_term>

| <set\_operation><set\_union\_op><set\_term>

Set operations are the operations which returns another set. It is defined as left associative. To make these happen, it has <set\_term> construct after the operators. Operator for the intersection is ‘^’, operator for the union is ‘U’ and operator for difference is ‘\’. The selection of these symbols is because of the fact that they resemble their mathematical notations.

For precedence, it is left associative but the parenthesis can be used because of the definition of <set\_term>. Usage of parenthesis to help precedence increases the writability of Dominica.

* <set\_term> ::= <set\_identifier> | <set>  | <LP><set\_operation><RP>

<set\_term> is defined for making the set operations left associative and also including precedence of parathesis. To be able to make this, <set\_term> can be a <set\_operation> with parathesis.

**Arithmetic Operations**

* <arithmetic\_operation> ::= <arithmetic\_term>

| <arithmetic\_operation><sign><arithmetic\_term>

Arithmetic operations in Dominica are left associative. Also, there is precedence of multiplication and division if there is not any parenthesis. If there are parenthesis, the expression with it has precedence. To make the arithmetic operation left associative, we include <arithmetic\_term> in the BNF definition of <arithmetic\_operation> and it is at the right of <sign>(+ or -).

* <arithmetic\_term> ::= <arithmetic\_term><mul\_div\_sign><arithmetic\_factor>

| <arithmetic\_factor>

<arithmetic\_term> construct includes <mul\_div\_sign> in its definition. This is for the precedence of multiplication and division to addition and subtraction. It also includes <arithmetic\_factor> construct, which helps for the precedence of parenthesis to multiplication and division.

* <arithmetic\_factor> ::= <LP><arithmetic\_operation><RP> | <identifier> | <integer>

| <double>

<arithmetic\_factor> is either one of the numerical variables or an identifier or an <arithmetic\_operation> inside parenthesis. This is because of the precedence of parenthesis. To be more precise, it is either a base case for the variables or a call to an arithmetic operation which is in the form of (<arithmetic\_operation).

**Loops**

* <loop\_stmt> ::= <for\_loop> | <while\_loop>

Loops are divided into two categories, for loop and while loop, in Dominica.

* <for\_loop> ::= <reg\_for\_loop> | <set\_for\_loop>

For loop is also divided into two subcategories which are regular for loop and set for loop. Both of these for loops should start with the keyword “for”

* <reg\_for\_loop>::= for<LP><variable\_declaration><end\_of\_stmt><logical\_expression><end\_of\_stmt><assignment\_expression><RP><LB><stmt\_list><RB>

After the keyword, the user should open a parantheses pair, “(“, “)”. Inside of this parantheses, the user needs to declare a variable followed by a semi column, “;”. For example,“int counter = 0;”. After the declaration of the variable, the loop needs a condition which is a logical expression followed by a semi column, “;”. Finally, inside of the parantheses, loop action, that is executed at the end of the each iteration, should be determined by assigning new expression to the initial variable. After the parantheses, curly braces, “{“, “}”, should contain at least one statement that is executed in each iteration.

* <set\_for\_loop>::=  
  for<LP><set\_identifier><column><set\_identifier><RP><LB><stmt\_list><RB> | for<LP><set\_identifier><column><integer><column><set\_identifier><RP><LB><stmt\_list><RP> | for<LP><set\_identifier><column><integer><column><identifier><RP><LB><stmt\_list><RP>

Set for loop is designed in order for the user to iterate some subsets more easily. There are two possible way to execute this loop. Inside of the curly braces, “{“, “}”, the first thing that is needed is have a set whose subsets are wondered. After that, we can have a set that does not have to be defined previously. For example, “for(\_mySet : \_subsetsOfMySet)” will allow the user to print every subset of the \_mySet by just accessing the \_subsetsOfMySet iterator. This looks like the enhanced for loop in other programming languages. Also another way to execute this loop is to have an integer constant between the first set and second iterator set. In this way, n element subsets can be displayed in each iteration. For example, “for(\_mySet : 2: \_twoElementSubsets)” will allow user to print twoElementSubsets of \_mySet variable. If the integer constant is 1, the user can have the type “elm” instead of a set in the very right of the set for loop’s parantheses. After the parantheses, the loop body should be inside of the curly braces, “{“, “}”.

* <while\_loop> ::= while<LP><logical\_expression><RP><LB><stmt\_list><RB>

A while loop should start with the keyword “while”. After that, the user should define a loop condition inside of parentheses, “(“, “)”. The loop condition is just a logical expression that is defined below. After the parentheses, the loop statements should be inside of the curly braces, “{“, “}”.

**Conditions**

* <conditional\_stmt> ::= if<LP><logical\_expression><RP><LB><stmt\_list><RB>

| if<LP><logical\_expression><RP><LB><stmt\_list><RB>else<LB><stmt\_list><RB> | if<LP><logical\_expression><RP><LB><stmt\_list><RB>else<conditional\_stmt>

The conditional statements are “if”, “else”, and “else if” statements. Each conditional block should start with one of the keywords above and should specify the logical expression inside of the parenthesis, “(“, “)”. After that the whole block must be inside of a curly braces opening and closing, “{“, “}”.

**Logical Expressions**

* <logical\_expression> ::= <regular\_logic> | <set\_logic>  
   | <logical\_expresion><and\_op><regular\_logic>  
   | <logical\_expresion><or\_op><regular\_logic>

| <logical\_expresion><and\_op><set\_logic>  
 | <logical\_expresion><or\_op><set\_logic>

| <exclamation\_mark><LP><logical\_expression><RP>

A <logical\_expression> consists of one or more <regular\_logic> and <set\_logic> following each other, separated by an <or\_op> (which is “||”) or by an <and\_op> (which is “&&”). <set\_logic> and <regular\_logic> are separated because sets cannot be used with the same operators as others types. Each logical expression value may be inversed if an <exclamation\_mark>(which is “!”) is placed before it; then if the value of the logical expression is true it will become false, and vice versa.

* <regular\_logic> ::= <regular\_logic\_types>

| <regular\_logic\_types><equals\_op><regular\_logic\_types>

| <arithmetic\_operation><equals\_op><arithmetic\_operation>

| <regular\_logic\_types><not\_equals\_op><regular\_logic\_types>

| <arithmetic\_operation><not\_equals\_op><arithmetic\_operation>

|<arithmetic\_operation><greater\_equal\_op><arithmetic\_operation>

| <arithmetic\_operation><less\_equal\_op><arithmetic\_operation>

| <arithmetic\_operation><greater\_than\_op><arithmetic\_operation>

| <arithmetic\_operation><less\_than\_op><arithmetic\_operation>

<regular\_logic> uses <regular\_logic\_types> and <arithmetic\_operation> as operands. The operators <equals\_op> (“==”) and <not\_equals\_op> (“!”) can be used with both <<regular\_logic\_types> and < arithmetic\_operation>. Whereas, <greater\_equal\_op>, <less\_equal\_op>, <greater\_than\_op> and <less\_than\_op> (respectively “>=”, “<=”, “>” and “<”) can only be used with <arithmetic\_operation>.

* <regular\_logic\_types> ::= <bool> | <identifier>

<bool> and <identifier> both belong to <regular\_logic\_types> because they can be used with the same logical operators.

* <set\_logic> ::= <identifier><set\_is\_an\_element\_of><set>

| <type><set\_is\_an\_element\_of><set>

| <identifier><set\_is\_an\_element\_of><set\_identifier>

| <type><set\_is\_an\_element\_of><set\_identifier>

| <set\_operation><set\_is\_subset><set\_operation>

| <set\_operation><set\_is\_superset><set\_operation>

| <set\_operation><set\_are\_disjoint><set\_operation>

The operator <set\_is\_an\_element\_of> ‘E’ is used to know if the <identifier> or the <type> placed before it, belongs to the set placed after. The operator <set\_is\_subset> ‘C’ is used when we have to know whether all the elements of the set placed before it also belongs to the set after. ‘@’ operator is the contrary, it is used to know if the first set is a superset of the second one. And finally, the <set\_are\_disjoint> operator ‘D’ is to know is two sets are disjoint. These symbols enhance the readability of the language because they look like mathematical ones, but also decrease the writability, forcing us to have <identifier> that are at least 2-characters-long.

**Functions**

* <function> ::= <type\_name><function\_identifier><LP><RP><LB><stmt\_list><return><identifier><RB>

|<type\_name><function\_identifier><LP><RP><LB><stmt\_list><return><set\_identifier><RB>

| <type\_name><function\_identifier><LP><RP><LB><stmt\_list><return><type><RB>

|<type\_name><function\_identifier><LP><RP><LB><stmt\_list><return><set><RB>

|<type\_name><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><identifier><RB>

|<type\_name><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><set\_identifier><RB>

|<type\_name><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><type><RB>

|<type\_name><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><set><RB> <set\_type><function\_identifier><LP><RP><LB><stmt\_list><return><identifier><RB> | <set\_type><function\_identifier><LP><RP><LB><stmt\_list><return><set\_identifier><RB> |   
<set\_type><function\_identifier><LP><RP><LB><stmt\_list><return><type><RB> | <set\_type><function\_identifier><LP><RP><LB><stmt\_list><return><set><RB> | <set\_type><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><identifier><RB> |   
<set\_type><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><set\_identifier><RB> | <set\_type><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><type><RB> |<set\_type><function\_identifier><LP><param\_list><RP><LB><stmt\_list><return><set><RB

Dominica’s function declaration should start with the return type which can be either a set or regular variables. After that, we need to have the indicator “func\_” at the beginning of the naming of the function. After that we open a left parantheses, “(“ to start the define parameters that the function will get. After defining zero or more parameters, we can close the parentheses with right parantheses, “)”. After that the function block should be inside of curly braces with at least one statement. The function should return something even though its intention is not return anything. Here is an example of a function declaration:

int func\_double(int myInt)

{

int newInt = myInt \* 2;

return newInt;

}

This implementation is close to some well-known languages. Therefore, it increases readability, writability and reliability.

* <function\_call> ::= <function\_identifier><LP><RP>

| <function\_identifier><LP><arg\_list><RP>

| <primitive\_function\_call>

<function\_call> may be used when calling a function that was declared. To call a function, the function name must be written in the first place followed by parentheses which contains or not an argument list. Moreover, it can also be a call to a primitive function already defined in Dominica.

* <primitive\_function\_call> ::= n<LP><set\_operation><RP>

| pow<LP><set\_operation><RP>

| cartesian<LP><set\_operation><comma><set\_operation><RP>

| print<LP><set\_operation><RP>

| print<LP><string><RP>

| print<LP><identifier><RP>

         | scan<LP><identifier><RP>

| scan<LP><set\_identifier><RP>

| fread<LP><string><RP>

| fwrite<LP><string><comma><string><RP>

| fwrite<LP><set\_operation><comma><string><RP>

<primitive\_function\_call> refers to a call to any of the primitive function. They are called the same way as non-primitive function.

n function returns the cardinality (number of elements) of the set given in argument.

cartesian function returns the cartesian product of the two sets given as arguments and display them on the console. Since we are not suppose to have any set in a set, we display the results instead of returning a set.

pow function displays all the power sets of the set given as argument on the console. Since we are not suppose to have any set in a set, we display the results instead of returning a set.

print function displays every element of the set given in argument on the console.

If an <identifier> is put as an argument, it will just displays its value on the console.

Scan function is used for taking an input from the user on the console.

fread function read the file given as argument.

And finally fwrite function is used to write a <string> or a <set\_operation> to a file.

**Lists**

* <arg\_list> ::= <identifier> | <set\_identifier> | <identifier><comma><param\_list>

| <set\_identifier><comma><param\_list>

In Dominica, while calling primitive or user-defined functions, users may pass some arguments to the function. Arguments may be the regular identifiers such as integer, string, bool, double, or elm as well as the set identifiers which start with the indicator “\_”. More than one arguments should be separated by comma.

* <param\_list> ::= <type\_name><identifier> | <set\_type><set\_identifier>

| <type\_name><identifier><comma><param\_list>

| <set\_type><set\_identifier><comma><param\_list>

In Dominica, while defining some functions, the user may want to have some parameters that is passed when the function is called. All of the parameters may be the regular identifiers as well as the set identifiers. All of the parameters should define the type followed by the identifier. If there are more than one parameters, they should be separated by comma.

**Comments**

* <comment\_stmt> ::= <line\_comment\_start><string\_term>

All of the comments in Dominica have to start with <line\_comment\_start>, which is the symbol ‘#’. This obligation increases the readability and reliability because it prevents mixing the identifiers and comments. Then, it has to be followed by a <string\_term>.

**Non-Trivial Tokens of Dominica**

**MAIN:** Token to indicate the start of the program.

**IF:** Token to indicate conditional statement if-else.

**ELSE:** Token to indicate conditional statement if-else.

**WHILE:** Token to indicate while loop.

**FOR:** Token to indicate for loop

**RETURN:** Token to return variable in functions.

**BOOL\_VALUE:** Token to indicate bool values “true” and “false”.

**LB:** Token to indica left braces “{“.

**RB:** Token to indicate right braces “}”.

**LP:** Token to indicate left parenthesis “(“.

**RP:** Token to indicate right parenthesis “)”.

**COMMA:** Token to indicate comma “,”.

**COLUMN:** Token to indicate column “:”.

**NOT\_OP:** Token to indicate not operation symbol “!” for logical operations.

**AND\_OP:** Token to indicate and operation symbol “&&” for logical operations.

**OR\_OP:** Token to indicate or operation symbol “||” for logical operations.

**ASSIGNMENT\_OP:** Token to indicate assignment operations symbol “=”.

**EQUALS\_OP:** Token to indicate equals operation symbol “==” for logical operations.

**NOT\_EQUALS\_OP:** Token to indicate not equals operation symbol “!=” for logical operations.

**GREATER\_THAN\_OP:** Token to indicate greater than operation symbol “>” for logical operations.

**GREATER\_EQUAL\_OP:** Token to indicate greater than or equal operation symbol “>=” for logical operations.

**LESS\_THAN\_OP:** Token to indicate less than operation symbol “<” for logical operations.

**LESS\_EQUAL\_OP:** Token to indicate less than or equal operation symbol “<=” for logical operations.

**VARIABLE\_TYPE:** Token to indicate reserved words “int”, “double”, “string”, “bool, for variables.

**SET\_ELEMENT\_TYPE:** Token to indicate reserved word “elm” for element variable, which can be any type among integer, double, string and bool.

**SET\_VARIABLE\_TYPE:** Token to indicate reserved word “set” for set variable.

**NEW\_LINE:** Token to indicate new lines.

**ADDITION\_OP:** Token to indicate summation symbol “+” for arithmetic operations.

**SUBTRACTION\_OP:** Token to indicate subtraction symbol “-“ for arithmetic operations.

**DIVISION\_OP:** Token to indicate division symbol “\” for arithmetic operations.

**MULTIPLICATION\_OP:** Token to indicate multiplication symbol “\*” for arithmetic operations.

**SET\_ADDITION\_OP:** Token to indicate the symbol “++” for adding a new element to a set.

**SET\_REMOVE\_OP:** Token to indicate the symbol “--“ for removing an element from the set.

**SET\_UNION\_OP:** Token to indicate the symbol “U” for taking the union of two sets.

**SET\_INTERSECTION\_OP:** Token to indicate the symbol “^” for taking the intersection of two sets.

**SET\_DIFFERENCE\_OP:** Token to indicate the symbol “\” for finding the difference of two sets.

**SET\_CARDINALITY:** Token to indicate reserved word “n” for primitive function identifier of cardinality function.

**SET\_POWER\_SET:** Token to indicate reserved word “pow” for primitive function identifier of power function.

**SET\_CARTESIAN:** Token to indicate reserved word “cartesian” for primitive function identifier of cartesian function.

**SET\_DELETE\_SET:** Token to indicate reserved word “delete” for deleting a set.

**SET\_IS\_SUBSET\_OF:** Token to indicate the symbol “C” for set logic operations which checks if the first set is a subset of the second set.

**SET\_IS\_SUPERSET\_OF:** Token to indicate the symbol “@” for set logic operations which checks if the first set is the superset of the second set.

**SET\_IS\_AN\_ELEMENT\_OF:** Token to indicate the symbol “E” for set logic operations. which checks if a variable is the element of given set.

**SET\_ARE\_DISJOINT:** Token to indicate the symbol “D” for set logic operations which checks if the given sets are disjoint.

**SCAN\_INPUT:** Token to indicate reserved word “scan” for primitive function identifier of scan function, which takes input from the user.

**FILE\_WRITE:** Token to indicate reserved word “fwrite” for primitive function identifier of file write function, which writes data to a file.

**FILE\_READ:** Token to indicate reserved word “fread” for primitive function identifier of file read function, which reads data from a file.

**PRINT:** Token to indicate reserved word “print” for primitive function identifier of print function, which prints the string or set content to console.

**END\_OF\_STMT:** Token to indicate symbol “;” which has to be put at the end of statements.

**INTEGER\_CONST:** Token to indicate integers.

**DOUBLE\_CONST:** Token to indicate doubles.

**COMMENT:** Token to indicate comments.

**STRING\_CONST:** Token to indicate strings.

**FUNCTION\_IDENTIFIER:** Token to indicate function identifiers which are for only functions. They start with “func\_”.

**SET\_IDENTIFIER:** Token to indicate set identifiers which are only for sets. They start with “\_”.

**IDENTIFIER:** Token to indicate variable identifiers. They have to start with a letter and they have to be minimum two-character length.